***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 24, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5528-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.7
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=132  VTO=2.25  LEVEL=3  VMAX=1e5  ETA=0.006  nfs=2.5e11  gamma=1.04)
Rd     d1    d2    3.63m TC=3.79m,10u
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=33  TBV1=4.355e-4  TBV2=-8e-7 CJO=9.761e-10  M=0.826  VJ=8.859)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=6.92e-12  N=1.086  RS=12.04u  EG=1.16  TT=20n ikf=45.97)
Rdiode  d1  21   2.67e-3 TC=3.5m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.520e-10
.MODEL     DGD    D(M=1.251   CJO=1.458e-10   VJ=6.197)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    5.971e-10
.ENDS
*$
